blob: 7164159523878261dc5937e922247d6b16bda061 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit pam toolchain-funcs fcaps
DESCRIPTION="Netkit's Remote Shell Suite: rexec{,d} rlogin{,d} rsh{,d}"
HOMEPAGE="ftp://ftp.uk.linux.org/pub/linux/Networking/netkit/"
SRC_URI="ftp://ftp.uk.linux.org/pub/linux/Networking/netkit/${P}.tar.gz
mirror://gentoo/rexec-1.5.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="pam"
RDEPEND="
sys-libs/ncurses:=
virtual/libcrypt:=
pam? ( >=sys-auth/pambase-20080219.1 )"
DEPEND="${RDEPEND}"
BDEPEND="app-arch/xz-utils"
PATCHES=(
"${FILESDIR}"/patches/
)
FILECAPS=( cap_net_bind_service usr/bin/r{cp,login,sh} )
src_prepare() {
# This must happen before patches are applied
rm -r rexec || die
mv ../rexec rexec || die
default
if tc-is-cross-compiler ; then
# Can't do runtime tests when cross-compiling
sed -i -e "s|./__conftest|: ./__conftest|" configure || die
fi
}
src_configure() {
tc-export CC
${CONFIG_SHELL:-/bin/sh} ./configure $(usex pam '' '--without-pam') || die
sed -i \
-e "s|-pipe -O2|${CFLAGS}|" \
-e "/^LDFLAGS=$/d" \
-e "s|-Wpointer-arith||" \
MCONFIG || die
}
src_install() {
insinto /etc/xinetd.d
local b
for b in rcp rexec{,d} rlogin{,d} rsh{,d} ; do
if [[ ${b} == *d ]] ; then
dosbin ${b}/${b}
dosym ${b} /usr/sbin/in.${b}
doman ${b}/${b}.8
else
dobin ${b}/${b}
doman ${b}/${b}.1
if [[ ${b} != rcp ]]; then
newins "${FILESDIR}"/${b}.xinetd ${b}
if use pam; then
newpamd "${FILESDIR}/${b}.pamd-pambase" ${b}
fi
fi
fi
done
dodoc README ChangeLog BUGS
newdoc rexec/README README.rexec
}
|
GitWeb