media-libs/libfpx/libfpx-1.3.1_p10.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit flag-o-matic libtool

DESCRIPTION="A library for manipulating FlashPIX images"
HOMEPAGE="https://github.com/ImageMagick/libfpx"
SRC_URI="mirror://imagemagick/delegates/${P/_p/-}.tar.bz2"

LICENSE="Flashpix"
SLOT="0/1"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="static-libs"

S=${WORKDIR}/${P/_p/-}

PATCHES=(
	"${FILESDIR}"/${PN}-1.2.0.13-export-symbols.patch
	"${FILESDIR}"/${PN}-1.3.1_p10-musl-1.2.3-null.patch
)

src_prepare() {
	default

	# we're not windows, even though we don't define __unix by default
	[[ ${CHOST} == *-darwin* ]] && append-flags -D__unix

	elibtoolize
}

src_configure() {
	# -Werror=strict-aliasing
	# https://bugs.gentoo.org/859913
	# https://github.com/ImageMagick/libfpx/issues/6
	#
	# Do not trust for LTO either
	append-flags -fno-strict-aliasing
	filter-lto

	append-ldflags -Wl,--no-undefined
	econf \
		$(use_enable static-libs static) \
		LIBS="-lstdc++ -lm"
}

src_install() {
	default

	dodoc AUTHORS ChangeLog doc/*.txt

	docinto pdf
	dodoc doc/*.pdf
	docompress -x /usr/share/doc/${PF}/pdf
}