blob: 75b8c4278d3a69d7c6c3c72427e3fcfff311bfe3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit virtualx autotools
DESCRIPTION="Bindings for GObject Introspection and libgirepository for Guile"
HOMEPAGE="https://spk121.github.io/guile-gi/"
if [[ "${PV}" == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/spk121/${PN}.git"
else
SRC_URI="https://github.com/spk121/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64"
fi
LICENSE="GPL-3"
SLOT="0"
DEPEND="
>=dev-scheme/guile-2.0.9:=
dev-libs/gobject-introspection
x11-libs/gtk+:3[introspection]
"
RDEPEND="${DEPEND}"
BDEPEND="sys-apps/texinfo"
# guile generates ELF files without use of C or machine code
# It's a portage's false positive. bug #677600
QA_PREBUILT='*[.]go'
src_prepare() {
default
# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
find "${S}" -name "*.scm" -exec touch {} + || die
eautoreconf
}
src_configure() {
econf --disable-static --enable-introspection=yes
}
src_test() {
virtx default
}
src_install() {
default
mv "${D}"/usr/share/doc/${PN} "${D}"/usr/share/doc/${PF} || die
find "${ED}" -type f -name '*.la' -delete || die
# Workaround llvm-strip problem of mangling guile ELF debug
# sections. Bug https://bugs.gentoo.org/905898
dostrip -x /usr/$(get_libdir)/guile
}
|
GitWeb
