From 0b3fa6aea4dc2f498b67bcebe8263f8f59df3d33 Mon Sep 17 00:00:00 2001
From: Mike Gilbert <floppym@gentoo.org>
Date: Fri, 13 Jan 2023 12:57:27 -0500
Subject: net-vpn/vpnc: use upstream systemd unit

Closes: https://bugs.gentoo.org/884093
Signed-off-by: Mike Gilbert <floppym@gentoo.org>
---
 net-vpn/vpnc/vpnc-0.5.3_p20220927-r1.ebuild | 89 +++++++++++++++++++++++++++++
 1 file changed, 89 insertions(+)
 create mode 100644 net-vpn/vpnc/vpnc-0.5.3_p20220927-r1.ebuild

(limited to 'net-vpn')

diff --git a/net-vpn/vpnc/vpnc-0.5.3_p20220927-r1.ebuild b/net-vpn/vpnc/vpnc-0.5.3_p20220927-r1.ebuild
new file mode 100644
index 000000000000..5f4e12444a64
--- /dev/null
+++ b/net-vpn/vpnc/vpnc-0.5.3_p20220927-r1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info systemd tmpfiles toolchain-funcs
+
+DESCRIPTION="Free client for Cisco VPN routing software"
+HOMEPAGE="https://www.unix-ag.uni-kl.de/~massar/vpnc/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/streambinder/vpnc.git"
+else
+	inherit vcs-snapshot
+	SRC_URI="
+		https://api.github.com/repos/streambinder/vpnc/tarball/fdd0de7 -> ${P}.tar.gz
+		https://dev.gentoo.org/~soap/distfiles/${PN}-0.5.3-docs.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="resolvconf +gnutls selinux"
+RESTRICT="!gnutls? ( bindist )"
+
+DEPEND="
+	dev-libs/libgcrypt:=
+	sys-apps/iproute2[-minimal]
+	gnutls? ( net-libs/gnutls:= )
+	!gnutls? ( dev-libs/openssl:= )"
+RDEPEND="${DEPEND}
+	>=net-vpn/vpnc-scripts-20210402-r1
+	resolvconf? ( virtual/resolvconf )
+	selinux? ( sec-policy/selinux-vpn )"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig"
+
+CONFIG_CHECK="~TUN"
+
+src_unpack() {
+	if [[ ${PV} == *9999 ]]; then
+		git-r3_src_unpack
+	else
+		vcs-snapshot_src_unpack
+		mv vpnc-0.5.3-docs/src/doc/*.md "${S}"/src/doc/ || die
+	fi
+}
+
+src_configure() {
+	tc-export CC PKG_CONFIG
+	export OPENSSL_GPL_VIOLATION=$(usex !gnutls)
+}
+
+src_install() {
+	local args=(
+		PREFIX="${EPREFIX}"/usr
+		DOCDIR='$(PREFIX)'/share/doc/${PF}
+		SYSTEMDDIR="$(systemd_get_systemunitdir)"
+		DESTDIR="${D}"
+	)
+
+	emake "${args[@]}" install
+
+	keepdir /etc/vpnc/scripts.d
+	newinitd "${FILESDIR}"/vpnc-3.init vpnc
+	newconfd "${FILESDIR}"/vpnc.confd vpnc
+
+	# LICENSE file resides here, should not be installed
+	rm -r "${ED}"/usr/share/licenses || die
+}
+
+pkg_postinst() {
+	tmpfiles_process vpnc-tmpfiles.conf
+
+	elog "You can generate a configuration file from the original Cisco profiles of your"
+	elog "connection by using /usr/bin/pcf2vpnc to convert the .pcf file"
+	elog "A guide is available at https://wiki.gentoo.org/wiki/Vpnc"
+
+	if use gnutls; then
+		elog "Will build with GnuTLS (default) instead of OpenSSL so you may even redistribute binaries."
+		elog "See the Makefile itself and https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=440318"
+	else
+		ewarn "Building SSL support with OpenSSL instead of GnuTLS. This means that"
+		ewarn "you are not allowed to re-distibute the binaries due to conflicts between BSD license and GPL,"
+		ewarn "see the vpnc Makefile and https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=440318"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad