From 487b734c23a776d353b472c06ddb0f5d0cb07b1c Mon Sep 17 00:00:00 2001
From: Martin Gysel <me@bearsh.org>
Date: Thu, 9 Jun 2022 21:15:39 +0200
Subject: dev-vcs/git-cola: version bump to 4.0.1, migrate to pep517 builds

Closes: https://bugs.gentoo.org/850784

Signed-off-by: Martin Gysel <me@bearsh.org>
Closes: https://github.com/gentoo/gentoo/pull/25838
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 dev-vcs/git-cola/Manifest              |  1 +
 dev-vcs/git-cola/git-cola-4.0.1.ebuild | 78 ++++++++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+)
 create mode 100644 dev-vcs/git-cola/git-cola-4.0.1.ebuild

(limited to 'dev-vcs')

diff --git a/dev-vcs/git-cola/Manifest b/dev-vcs/git-cola/Manifest
index 6d06c491524e..5b47987d3cdc 100644
--- a/dev-vcs/git-cola/Manifest
+++ b/dev-vcs/git-cola/Manifest
@@ -1,3 +1,4 @@
 DIST git-cola-3.10.1.tar.gz 996036 BLAKE2B 2d705b853cf67a0f437d8dc77d46d5804124af600f872717c832843586d3c739e67a79ebe50ba2a8db38afd4217a7bb94db9cb8e27d51a00087ced340f4877d6 SHA512 79496023bfaa05049079eec2cdaf8449a6598faebedb4a13acf178209edc63e725eb1b003700a1dcfee09072d34e5a49d7053f070e45b498562cc124cd0582d4
 DIST git-cola-3.11.0.tar.gz 997046 BLAKE2B 7a8270c30e0cbd919dcd6f8e38ca420257630717e535ef11ed337fde2461b544453b20363906a5b769cd23d96ca77ce72d71729f46ae6abada83ae4d33628cbc SHA512 f05862b9b27ff5dfe9b220bbee4f3f455a7ce98acaa0bb0a8cdbb44f8cb97ce265df036ba48d5abb0bf46a91fd782cd73a67ca544b4662d36e8023e92c80b541
 DIST git-cola-3.12.0.tar.gz 1004892 BLAKE2B 9396768256341e59500dffc95136e710b2d3d1c9d5cb4d70fc7fba8e81e16a3656006b5558dae417fbbad7baf1373d953708006b96a8873f68502ea469462326 SHA512 4b8ec716f572682747f43ae1a9232612d95d44384d28bbf97ef461a93546cdfcc81125f816b4c8ea5efcf4d23f42edeb8a89df3c7167ceac4709eeeaf49965a9
+DIST git-cola-4.0.1.tar.gz 1018819 BLAKE2B 523264bbee38526d12db5ad975d78c72ef6c0dae98566f5a8b5d51b115d222c8aa6daab838ba67fa4c697391c8f58d4b05ddb7920bf65913d217f562aabd352f SHA512 c02150997982c1f8ce65a5f021364fc4c346339f5be4104f82ba6f7688cc05bad3d764e2cf920a22c5f209dc4b857c789907ff58c0d2809bc7ca7c3481b045fd
diff --git a/dev-vcs/git-cola/git-cola-4.0.1.ebuild b/dev-vcs/git-cola/git-cola-4.0.1.ebuild
new file mode 100644
index 000000000000..dc640bd0539b
--- /dev/null
+++ b/dev-vcs/git-cola/git-cola-4.0.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_SINGLE_IMPL=true
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 readme.gentoo-r1 virtualx xdg-utils
+
+DESCRIPTION="The highly caffeinated git GUI"
+HOMEPAGE="https://git-cola.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/QtPy[gui,network,${PYTHON_USEDEP}]
+		dev-python/send2trash[${PYTHON_USEDEP}]
+	')
+	dev-vcs/git
+"
+BDEPEND="sys-devel/gettext
+	$(python_gen_cond_dep "
+		test? (
+			${VIRTUALX_DEPEND}
+			dev-python/pytest[\${PYTHON_USEDEP}]
+			dev-python/PyQt5[\${PYTHON_USEDEP},gui,widgets]
+		)
+	")
+"
+
+# right now, dev-python/jaraco-packaging is mask, so we cannot generate docs
+#distutils_enable_sphinx docs \
+#	'>=dev-python/jaraco-packaging-9' \
+#	'dev-python/rst-linker'
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i "s|doc/git-cola =|doc/${PF} =|" setup.cfg || die
+	sed -i -e 's:--flake8::' pytest.ini || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	cd "${T}" || die
+	GIT_CONFIG_NOSYSTEM=true LC_ALL="C.utf8" \
+	epytest "${S}"/test
+}
+
+src_compile() {
+	SETUPTOOLS_SCM_PRETEND_VERSION=${PV} distutils-r1_src_compile
+}
+
+src_install() {
+	distutils-r1_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3-65-gdbad