From db2964fd91162c3022b5e381f3fe71765822bc79 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Sun, 14 May 2023 13:55:32 +0200
Subject: dev-tex/latex2rtf: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>
---
 dev-tex/latex2rtf/latex2rtf-2.3.15-r1.ebuild | 48 +++++++++++++++++++++++++++
 dev-tex/latex2rtf/latex2rtf-2.3.15.ebuild    | 49 ----------------------------
 2 files changed, 48 insertions(+), 49 deletions(-)
 create mode 100644 dev-tex/latex2rtf/latex2rtf-2.3.15-r1.ebuild
 delete mode 100644 dev-tex/latex2rtf/latex2rtf-2.3.15.ebuild

(limited to 'dev-tex/latex2rtf')

diff --git a/dev-tex/latex2rtf/latex2rtf-2.3.15-r1.ebuild b/dev-tex/latex2rtf/latex2rtf-2.3.15-r1.ebuild
new file mode 100644
index 000000000000..f1105ddeb5b2
--- /dev/null
+++ b/dev-tex/latex2rtf/latex2rtf-2.3.15-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="LaTeX to RTF converter"
+HOMEPAGE="http://latex2rtf.sourceforge.net/"
+SRC_URI="mirror://sourceforge/latex2rtf/${P}.tar.gz"
+S="${WORKDIR}/${P%b}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~hppa ~ia64 ppc ppc64 ~riscv sparc x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	virtual/latex-base
+	media-gfx/imagemagick"
+BDEPEND="${RDEPEND}
+	virtual/texi2dvi
+	test? (
+		dev-texlive/texlive-langgerman
+		dev-texlive/texlive-fontsrecommended
+		dev-texlive/texlive-latexextra
+		dev-tex/latex2html
+	)"
+
+src_compile() {
+	export VARTEXFONTS="${T}"/fonts
+
+	tc-export CC
+	# Set DESTDIR here too so that compiled-in paths are correct.
+	emake DESTDIR="${EPREFIX}"/usr
+
+	# Needed for tests
+	chmod +x test/bracecheck || die
+
+	emake -C doc realclean
+	emake -C doc -j1
+}
+
+src_install() {
+	dodoc README* HACKING ToDo ChangeLog doc/credits
+	emake DESTDIR="${ED}"/usr -j1 install install-info
+}
diff --git a/dev-tex/latex2rtf/latex2rtf-2.3.15.ebuild b/dev-tex/latex2rtf/latex2rtf-2.3.15.ebuild
deleted file mode 100644
index 732b4e1aa03a..000000000000
--- a/dev-tex/latex2rtf/latex2rtf-2.3.15.ebuild
+++ /dev/null
@@ -1,49 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit toolchain-funcs
-
-DESCRIPTION="LaTeX to RTF converter"
-HOMEPAGE="http://latex2rtf.sourceforge.net/"
-SRC_URI="mirror://sourceforge/latex2rtf/${P}.tar.gz"
-
-LICENSE="GPL-2"
-KEYWORDS="~alpha amd64 ~hppa ~ia64 ppc ppc64 ~riscv sparc x86"
-SLOT="0"
-IUSE="test"
-RESTRICT="!test? ( test )"
-S="${WORKDIR}/${P%b}"
-
-RDEPEND="
-	virtual/latex-base
-	media-gfx/imagemagick
-"
-DEPEND="${RDEPEND}
-	virtual/texi2dvi
-	test? (
-		dev-texlive/texlive-langgerman
-		dev-texlive/texlive-fontsrecommended
-		dev-texlive/texlive-latexextra
-		dev-tex/latex2html
-	)
-"
-
-src_compile() {
-	export VARTEXFONTS="${T}/fonts"
-	tc-export CC
-	# Set DESTDIR here too so that compiled-in paths are correct.
-	emake DESTDIR="${EPREFIX}/usr"
-
-	# Needed for tests
-	chmod +x test/bracecheck || die
-
-	cd "${S}/doc"
-	emake realclean
-	emake -j1
-}
-
-src_install() {
-	dodoc README* HACKING ToDo ChangeLog doc/credits
-	emake DESTDIR="${ED}/usr" -j1 install install-info
-}
-- 
cgit v1.2.3-65-gdbad