From dcdbc7dfcafb6644f48f00c7d75cbc153d4f5c31 Mon Sep 17 00:00:00 2001
From: Louis Sautier <sautier.louis@gmail.com>
Date: Sat, 30 Apr 2016 02:55:29 +0200
Subject: dev-python/jaraco-stream: initial version 1.1

new dependency for dev-python/irc

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/1376

Signed-off-by: Ian Delaney <idella4@gentoo.org>
---
 dev-python/jaraco-stream/jaraco-stream-1.1.ebuild | 50 +++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-python/jaraco-stream/jaraco-stream-1.1.ebuild

(limited to 'dev-python/jaraco-stream/jaraco-stream-1.1.ebuild')

diff --git a/dev-python/jaraco-stream/jaraco-stream-1.1.ebuild b/dev-python/jaraco-stream/jaraco-stream-1.1.ebuild
new file mode 100644
index 000000000000..0f928f18a5d7
--- /dev/null
+++ b/dev-python/jaraco-stream/jaraco-stream-1.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Routines for handling streaming data"
+HOMEPAGE="https://github.com/jaraco/jaraco.stream"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	# Skip one test which requires network access
+	py.test --ignore=jaraco/stream/test_gzip.py \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad