From 5e6ab7bbb8bae984f628fa0255789a5ec8899864 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <andreas.sturmlechner@gmail.com>
Date: Sat, 10 Sep 2016 11:09:16 +0200
Subject: app-text/liblangtag: Add USE=debug,doc and sync ebuild fixes

Gentoo-bug: 593240

0.6.0 Version bump overlapped with commit 432384028d4eaf1060ca3f44b3f546187c9a195d

Package-Manager: portage-2.3.0
---
 app-text/liblangtag/liblangtag-0.6.0-r2.ebuild | 54 ++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 app-text/liblangtag/liblangtag-0.6.0-r2.ebuild

(limited to 'app-text/liblangtag')

diff --git a/app-text/liblangtag/liblangtag-0.6.0-r2.ebuild b/app-text/liblangtag/liblangtag-0.6.0-r2.ebuild
new file mode 100644
index 000000000000..3bca60009346
--- /dev/null
+++ b/app-text/liblangtag/liblangtag-0.6.0-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils xdg-utils
+
+DESCRIPTION="An interface library to access tags for identifying languages"
+HOMEPAGE="https://tagoh.bitbucket.org/liblangtag/"
+SRC_URI="https://bitbucket.org/tagoh/${PN}/downloads/${P}.tar.bz2"
+
+LICENSE="|| ( LGPL-3 MPL-2.0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="debug doc introspection static-libs test"
+
+RDEPEND="
+	dev-libs/libxml2
+	introspection? ( dev-libs/gobject-introspection )
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection-common )
+	test? ( dev-libs/check )
+"
+
+# Upstream expect liblangtag to be installed when one runs tests...
+RESTRICT="test"
+
+PATCHES=( "${FILESDIR}"/${P}-enum.patch )
+
+src_prepare() {
+	default
+	xdg_environment_reset
+	if [[ -d docs/html ]]; then
+		rm -r docs/html || die "Failed to remove existing gtk-doc"
+	fi
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_enable introspection) \
+		$(use_enable static-libs static) \
+		$(use_enable test)
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}
-- 
cgit v1.2.3-65-gdbad