From f9c2bf4c2cd9ccc09116ee0bc8b9accdd355f301 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Fri, 8 Nov 2024 21:01:31 +0100
Subject: app-misc/geoclue: add 2.7.2
Closes: https://bugs.gentoo.org/942130
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
---
app-misc/geoclue/Manifest | 1 +
app-misc/geoclue/geoclue-2.7.2.ebuild | 67 +++++++++++++++++++++++++++++++++++
2 files changed, 68 insertions(+)
create mode 100644 app-misc/geoclue/geoclue-2.7.2.ebuild
(limited to 'app-misc')
diff --git a/app-misc/geoclue/Manifest b/app-misc/geoclue/Manifest
index a1e946bba46a..d1f7cc9ec3de 100644
--- a/app-misc/geoclue/Manifest
+++ b/app-misc/geoclue/Manifest
@@ -1 +1,2 @@
DIST geoclue-2.7.1.tar.bz2 106458 BLAKE2B a2fc44d4941936d8dcd495d77d11b0d948d7031ca048b97ff0940c7fcdd37ba604655f2e255c5e0dd5cc7a82a2d5a15b18aab4825b2446560e225c13df6da3b8 SHA512 972663a6f8c969d0e1a5f911af2b8afed486d5c0ba06dadc19bcfbe1ea22cef10243b2bd0084e5c45b70977cfa5650c8f15f760e4bc4e7dbd946745b67c9188b
+DIST geoclue-2.7.2.tar.bz2 108472 BLAKE2B 7fdb7a2d844079df005c2a665131a5541e667367de9a95b6bb9a930f0063e194f98cb69bd4a668f81c8e6ce9cf86e25229fd0d6ef9c25406995052024466076c SHA512 2300fca3c088f1bef29ecf1b5c82f6e91fcf886f3aa9ce1e53054e0c430fb3fc810ae8f580469a7975942c5a4852c75bac123a58c7c389d0ef116dc324d6463c
diff --git a/app-misc/geoclue/geoclue-2.7.2.ebuild b/app-misc/geoclue/geoclue-2.7.2.ebuild
new file mode 100644
index 000000000000..53b9606a3c65
--- /dev/null
+++ b/app-misc/geoclue/geoclue-2.7.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="xml(+)"
+inherit meson python-any-r1 systemd vala xdg
+
+DESCRIPTION="Location information D-Bus service"
+HOMEPAGE="https://gitlab.freedesktop.org/geoclue/geoclue/-/wikis/home"
+SRC_URI="https://gitlab.freedesktop.org/geoclue/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+introspection gtk-doc modemmanager vala zeroconf"
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+ >=dev-libs/glib-2.74:2
+ >=dev-libs/json-glib-0.14.0
+ >=net-libs/libsoup-3.0.0:3.0
+ introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+ modemmanager? ( >=net-misc/modemmanager-1.12 )
+ zeroconf? ( >=net-dns/avahi-0.6.10[dbus] )
+ x11-libs/libnotify
+"
+RDEPEND="${DEPEND}
+ acct-user/geoclue
+ sys-apps/dbus
+"
+BDEPEND="${PYTHON_DEPS}
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ gtk-doc? (
+ app-text/docbook-xml-dtd:4.1.2
+ >=dev-util/gtk-doc-1 )
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+ default
+ use vala && vala_setup
+ xdg_environment_reset
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dlibgeoclue=true
+ $(meson_use introspection)
+ $(meson_use vala vapi)
+ $(meson_use gtk-doc)
+ $(meson_use modemmanager 3g-source)
+ $(meson_use modemmanager cdma-source)
+ $(meson_use modemmanager modem-gps-source)
+ $(meson_use zeroconf nmea-source)
+ -Dcompass=true
+ -Denable-backend=true
+ -Ddemo-agent=true
+ -Dsystemd-system-unit-dir="$(systemd_get_systemunitdir)"
+ -Ddbus-srv-user=geoclue
+ )
+ meson_src_configure
+}
--
cgit v1.2.3-65-gdbad