From e0acb12e881c720217546d7688bb763cb73e917d Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Sat, 14 May 2022 22:54:44 +0200
Subject: app-misc/g15composer: Added live ebuild

- new upstream

Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 app-misc/g15composer/g15composer-9999.ebuild | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 app-misc/g15composer/g15composer-9999.ebuild

(limited to 'app-misc/g15composer')

diff --git a/app-misc/g15composer/g15composer-9999.ebuild b/app-misc/g15composer/g15composer-9999.ebuild
new file mode 100644
index 000000000000..91ff7d33e957
--- /dev/null
+++ b/app-misc/g15composer/g15composer-9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="A library to render text and shapes into a buffer usable by the Logitech G15"
+HOMEPAGE="https://gitlab.com/menelkir/g15composer"
+if [[ ${PV} == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/menelkir/g15composer.git"
+else
+	SRC_URI="https://gitlab.com/menelkir/${PN}/-/archive/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="truetype"
+
+DEPEND="
+	>=app-misc/g15daemon-3.0
+	>=dev-libs/libg15render-3.0[truetype?]
+	truetype? ( media-libs/freetype	)
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable truetype ttf)
+}
+
+src_install() {
+	local DOCS=( AUTHORS README ChangeLog )
+	default
+
+	newinitd "${FILESDIR}/${PN}-3.2.initd" ${PN}
+	newconfd "${FILESDIR}/${PN}-3.2.confd" ${PN}
+}
+
+pkg_postinst() {
+	elog "Set the user to run g15composer in /etc/conf.d/g15composer before starting the service."
+}
-- 
cgit v1.2.3-65-gdbad