From 2a697673049e3e0b7f431cca0463e2667bc8eca2 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Sun, 11 Mar 2018 11:40:42 +0100
Subject: app-crypt/libnitrokey: Initial addition

Bug: https://bugs.gentoo.org/634474
Package-Manager: Portage-2.3.24, Repoman-2.3.6
---
 app-crypt/libnitrokey/libnitrokey-9999.ebuild | 50 +++++++++++++++++++++++++++
 app-crypt/libnitrokey/metadata.xml            | 12 +++++++
 2 files changed, 62 insertions(+)
 create mode 100644 app-crypt/libnitrokey/libnitrokey-9999.ebuild
 create mode 100644 app-crypt/libnitrokey/metadata.xml

(limited to 'app-crypt/libnitrokey')

diff --git a/app-crypt/libnitrokey/libnitrokey-9999.ebuild b/app-crypt/libnitrokey/libnitrokey-9999.ebuild
new file mode 100644
index 000000000000..32cf1940ee3a
--- /dev/null
+++ b/app-crypt/libnitrokey/libnitrokey-9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+inherit cmake-utils udev
+
+DESCRIPTION="Support library for the Nitrokey"
+HOMEPAGE="https://github.com/Nitrokey/libnitrokey"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Nitrokey/libnitrokey.git"
+
+	# Disable pulling in bundled dependencies
+	EGIT_SUBMODULES=()
+else
+	SRC_URI="https://github.com/Nitrokey/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/hidapi:=
+	virtual/udev"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	test? ( >=dev-cpp/catch-2.2.0 )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_UDEVRULESDIR="$(get_udevdir)"/rules.d
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DBUILD_SHARED_LIBS=ON
+
+		# actual hardware tests
+		#   1. require a connected Nitrokey
+		#   2. may kill data on your Nitrokey
+		# hence the main testsuite is disabled
+		-DCOMPILE_TESTS=OFF
+		-DCOMPILE_OFFLINE_TESTS=$(usex test)
+	)
+	cmake-utils_src_configure
+}
diff --git a/app-crypt/libnitrokey/metadata.xml b/app-crypt/libnitrokey/metadata.xml
new file mode 100644
index 000000000000..bea0c015c764
--- /dev/null
+++ b/app-crypt/libnitrokey/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>soap@gentoo.org</email>
+		<name>David Seifert</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">Nitrokey/libnitrokey</remote-id>
+		<bugs-to>https://github.com/Nitrokey/libnitrokey/issues</bugs-to>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3-65-gdbad