2 files changed, 95 insertions, 5 deletions
diff --git a/x11-wm/ratpoison/ratpoison-1.4.8-r1.ebuild b/x11-wm/ratpoison/ratpoison-1.4.8-r1.ebuild
new file mode 100644
index 000000000000..c98d3bd9e281
--- /dev/null
+++ b/x11-wm/ratpoison/ratpoison-1.4.8-r1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit elisp-common eutils toolchain-funcs
+
+DESCRIPTION="window manager without mouse dependency"
+HOMEPAGE="http://www.nongnu.org/ratpoison/"
+SRC_URI="http://download.savannah.gnu.org/releases/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
+IUSE="debug emacs +history sloppy +xft"
+
+RDEPEND="
+	emacs? ( virtual/emacs )
+	history? ( sys-libs/readline:= )
+	xft? ( x11-libs/libXft )
+	virtual/perl-Pod-Parser
+	x11-libs/libXinerama
+	x11-libs/libXtst
+"
+DEPEND="
+	${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+SITEFILE=50ratpoison-gentoo.el
+DOCS=( AUTHORS ChangeLog NEWS README TODO )
+
+src_prepare() {
+	epatch "${FILESDIR}"/ratpoison.el-gentoo.patch
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable history) \
+		$(use_with xft)
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+	if use emacs; then
+		elisp-compile contrib/ratpoison.el || die "elisp-compile failed"
+	fi
+
+	if use sloppy; then
+		pushd contrib
+		$(tc-getCC) \
+			${CFLAGS} \
+			${LDFLAGS} \
+			-o sloppy{,.c} \
+			$( $(tc-getPKG_CONFIG) --libs x11) \
+			|| die
+	fi
+}
+
+src_install() {
+	default
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/ratpoison.xsession ratpoison
+
+	insinto /usr/share/xsessions
+	doins "${FILESDIR}"/${PN}.desktop
+
+	use sloppy && dobin contrib/sloppy
+
+	docinto example
+	dodoc contrib/{genrpbindings,split.sh} \
+		doc/{ipaq.ratpoisonrc,sample.ratpoisonrc}
+
+	rm -rf "${ED}/usr/share/"{doc/ratpoison,ratpoison}
+
+	if use emacs; then
+		elisp-install ${PN} contrib/ratpoison.*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/x11-wm/ratpoison/ratpoison-9999.ebuild b/x11-wm/ratpoison/ratpoison-9999.ebuild
index 699bdec4435f..1e4fa29c8102 100644
--- a/x11-wm/ratpoison/ratpoison-9999.ebuild
+++ b/x11-wm/ratpoison/ratpoison-9999.ebuild
@@ -3,10 +3,9 @@
 # $Id$
 
 EAPI=5
-
 inherit autotools elisp-common eutils git-r3 toolchain-funcs
 
-DESCRIPTION="an extremely light-weight and barebones wm modelled after screen"
+DESCRIPTION="window manager without mouse dependency"
 HOMEPAGE="http://www.nongnu.org/ratpoison/"
 EGIT_REPO_URI="git://git.savannah.nongnu.org/ratpoison.git"
 
@@ -17,11 +16,11 @@ IUSE="debug emacs +history sloppy +xft"
 
 RDEPEND="
 	emacs? ( virtual/emacs )
-	history? ( sys-libs/readline )
+	history? ( sys-libs/readline:= )
+	xft? ( x11-libs/libXft )
 	virtual/perl-Pod-Parser
 	x11-libs/libXinerama
 	x11-libs/libXtst
-	xft? ( x11-libs/libXft )
 "
 DEPEND="
 	${RDEPEND}
@@ -33,7 +32,7 @@ SITEFILE=50ratpoison-gentoo.el
 DOCS=( AUTHORS ChangeLog NEWS README TODO )
 
 src_prepare() {
-	epatch "${FILESDIR}/ratpoison.el-gentoo.patch"
+	epatch "${FILESDIR}"/ratpoison.el-gentoo.patch
 	eautoreconf
 }