3 files changed, 160 insertions, 0 deletions
diff --git a/media-video/obs-studio/Manifest b/media-video/obs-studio/Manifest
index 53c9e37d7c2c..cf9867a4ab95 100644
--- a/media-video/obs-studio/Manifest
+++ b/media-video/obs-studio/Manifest
@@ -1,2 +1,3 @@
 DIST obs-studio-24.0.3.tar.gz 6285359 BLAKE2B f799e93e9c35c22e5d7f6e4da04e30b06a3a1ad1b3bfd0a75acdbb5d1f28a717d84809a1f35a858252ff30094fa80521d752a35b5285b0a606d0d77ff88fb3cf SHA512 57cef700076457da1eee344042261e1ada6d6744fcb3033a1d4eaffb9e84dd350aa198984fba3de82d4e727706f562c7c3568d95de6859a4942d9fa6368a02ab
 DIST obs-studio-24.0.5.tar.gz 7901198 BLAKE2B 79c9712f3523114a70e0df3e0631c19067fd7ead5fd9031123dd4c82d9b92dee69473fb51a495f938430540505a5cf45258eeee01d61a7aaa6654255fee14aca SHA512 99be46046b70597474f25a85036ebe5a2f704eef47c77bc27e2ba8890b877da346ff6008c5922d7a83a4cead9df7214c6a3be885430693e609a42d9d06fedfaf
+DIST obs-studio-25.0.0.tar.gz 8364710 BLAKE2B 20e48edb1fcb900bec464e970232a0cc920028455df51a8b7372f90ea96f1a614eba3b43c8f186fa2703cccad505a46f0a8e79b4f966c4964fd2542b460d9a85 SHA512 473bd8b749f52143768a550ca63a300e123be68654c9f5864c6e5c76ca0a74ad998cc24eef999dfb6189afada2b1f4c1d0cf3e45835ee27720429277ef1e10d6
diff --git a/media-video/obs-studio/obs-studio-25.0.0.ebuild b/media-video/obs-studio/obs-studio-25.0.0.ebuild
new file mode 100644
index 000000000000..33ca63777c33
--- /dev/null
+++ b/media-video/obs-studio/obs-studio-25.0.0.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit cmake-utils python-single-r1 xdg-utils
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git"
+	EGIT_SUBMODULES=()
+else
+	SRC_URI="https://github.com/obsproject/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Software for Recording and Streaming Live Video Content"
+HOMEPAGE="https://obsproject.com"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+alsa fdk imagemagick jack luajit nvenc pulseaudio python speex +ssl truetype v4l vlc"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="
+	luajit? ( dev-lang/swig )
+	python? ( dev-lang/swig )
+"
+DEPEND="
+	>=dev-libs/jansson-2.5
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtquickcontrols:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	media-libs/x264
+	media-video/ffmpeg:=[x264]
+	net-misc/curl
+	sys-apps/dbus
+	sys-libs/zlib
+	virtual/udev
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXfixes
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	alsa? ( media-libs/alsa-lib )
+	fdk? ( media-libs/fdk-aac:= )
+	imagemagick? ( media-gfx/imagemagick:= )
+	jack? ( virtual/jack )
+	luajit? ( dev-lang/luajit:2 )
+	nvenc? (
+		|| (
+			<media-video/ffmpeg-4[nvenc]
+			>=media-video/ffmpeg-4[video_cards_nvidia]
+		)
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	python? ( ${PYTHON_DEPS} )
+	speex? ( media-libs/speexdsp )
+	ssl? ( net-libs/mbedtls:= )
+	truetype? (
+		media-libs/fontconfig
+		media-libs/freetype
+	)
+	v4l? ( media-libs/libv4l )
+	vlc? ( media-video/vlc:= )
+"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local libdir=$(get_libdir)
+	local mycmakeargs=(
+		-DDISABLE_ALSA=$(usex !alsa)
+		-DDISABLE_FREETYPE=$(usex !truetype)
+		-DDISABLE_JACK=$(usex !jack)
+		-DDISABLE_LIBFDK=$(usex !fdk)
+		-DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
+		-DDISABLE_SPEEXDSP=$(usex !speex)
+		-DDISABLE_V4L2=$(usex !v4l)
+		-DDISABLE_VLC=$(usex !vlc)
+		-DLIBOBS_PREFER_IMAGEMAGICK=$(usex imagemagick)
+		-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
+		-DUNIX_STRUCTURE=1
+		-DWITH_RTMPS=$(usex ssl)
+	)
+
+	if [ "${PV}" != "9999" ]; then
+		mycmakeargs+=(
+			-DOBS_VERSION_OVERRIDE=${PV}
+		)
+	fi
+
+	if use luajit || use python; then
+		mycmakeargs+=(
+			-DDISABLE_LUA=$(usex !luajit)
+			-DDISABLE_PYTHON=$(usex !python)
+			-DENABLE_SCRIPTING=yes
+		)
+	else
+		mycmakeargs+=( -DENABLE_SCRIPTING=no )
+	fi
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! use alsa && ! use pulseaudio; then
+		elog
+		elog "For the audio capture features to be available,"
+		elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
+		elog "be enabled."
+		elog
+	fi
+
+	if ! has_version "sys-apps/dbus"; then
+		elog
+		elog "The 'sys-apps/dbus' package is not installed, but"
+		elog "could be used for disabling hibernating, screensaving,"
+		elog "and sleeping.  Where it is not installed,"
+		elog "'xdg-screensaver reset' is used instead"
+		elog "(if 'x11-misc/xdg-utils' is installed)."
+		elog
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/media-video/obs-studio/obs-studio-9999.ebuild b/media-video/obs-studio/obs-studio-9999.ebuild
index 998372506123..33ca63777c33 100644
--- a/media-video/obs-studio/obs-studio-9999.ebuild
+++ b/media-video/obs-studio/obs-studio-9999.ebuild
@@ -41,11 +41,19 @@ DEPEND="
 	dev-qt/qtsvg:5
 	dev-qt/qtwidgets:5
 	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	media-libs/x264
 	media-video/ffmpeg:=[x264]
 	net-misc/curl
+	sys-apps/dbus
+	sys-libs/zlib
+	virtual/udev
+	x11-libs/libX11
 	x11-libs/libXcomposite
+	x11-libs/libXfixes
 	x11-libs/libXinerama
 	x11-libs/libXrandr
+	x11-libs/libxcb
 	alsa? ( media-libs/alsa-lib )
 	fdk? ( media-libs/fdk-aac:= )
 	imagemagick? ( media-gfx/imagemagick:= )
@@ -91,6 +99,12 @@ src_configure() {
 		-DWITH_RTMPS=$(usex ssl)
 	)
 
+	if [ "${PV}" != "9999" ]; then
+		mycmakeargs+=(
+			-DOBS_VERSION_OVERRIDE=${PV}
+		)
+	fi
+
 	if use luajit || use python; then
 		mycmakeargs+=(
 			-DDISABLE_LUA=$(usex !luajit)