2 files changed, 69 insertions, 0 deletions
diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index 150c8c221014..820a08b43520 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.59.tar.gz 6822110 BLAKE2B ba6a9912886c8ac5a0506c0170232f7f441e10d3bff2a45309cf4b03a67465165438c2955d080d7dd2616c0404594d7af370f5ada13337d91d46c07713ddf1a2 SHA512 a66ae8aba0bab19c1ac4a68889a9134eb24ba01e4ae444eac96c6f6829a09d307884ed4b448b606e2c9fea21d2fe33df68f5cd982177fc8d2c4b366ee090cfaa
+DIST tucnak-4.60.tar.gz 6823505 BLAKE2B 4c0bea1a3f179f0ee8fe0b652f42148171c73b6b558f44c7ded86bc9964d08a13004c490fa4f9337ff92bf2c685b37682212171a0331cb47667a32019cc26ada SHA512 37f2820d451dae83ffdfe52e8a1a8a7195cb518a831b8e2d9553387c504a7407cf15a70d7744a2ed88585f12638c1ae3e62f47914b232e5b20f8b07d3c2fac8c
diff --git a/media-radio/tucnak/tucnak-4.60.ebuild b/media-radio/tucnak/tucnak-4.60.ebuild
new file mode 100644
index 000000000000..1fb016d217b3
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.60.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	~dev-libs/libzia-4.60
+	media-libs/libsndfile
+	media-libs/libsdl2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib:= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}