2 files changed, 57 insertions, 0 deletions
diff --git a/app-misc/yq/Manifest b/app-misc/yq/Manifest
index d6ba60e56cec..cac2fb398b93 100644
--- a/app-misc/yq/Manifest
+++ b/app-misc/yq/Manifest
@@ -1,2 +1,3 @@
 DIST yq-3.1.0.tar.gz 29627 BLAKE2B 9ebeec400462788613b256a29c9706f4d6a06ced8a86b72ce6128cea6bdf258a62ff18b643cea00d5170f68af798d28af324b3908fc3fdea83329bc5feaa5539 SHA512 bb55a9fde5c072d2341faacd76c54d7374fcc70789ddae4d06e36fd48d7ebd6462c8bff13042c39c3fedf191d70752fa2f94af3c69f52f754bca83c3f1f89004
 DIST yq-3.1.1.tar.gz 30095 BLAKE2B 0f8ed3d23e1c1b65fae0164f34b19ab774308ee8ec9b5c21547c5eddf930c49750cdbee858b6b48bcd92d4146715f7e4c45dd976141dc5837c788e4ae68a51bc SHA512 f6d372fd406179121849330391ab5657e9bac3b6fb4d33673872d4649337fd60344fe01c534d1382cc35416919cd19b62287350d1f0f825f198fb9cc9bc58c1f
+DIST yq-3.2.1.tar.gz 30333 BLAKE2B ead106995dcd03bc729aabd07c20dff37cf42053378f9d73c20739cb10921619999df73852d69f397431c4a382d40735c751aff9676d66ab9edbc5480a5c6807 SHA512 5b696434c9b6520873f4b956370fe598e3ac8df544d8b4ebc0d7fa935d344e58d9b838f2133b02c9e35a8afc5193c309d36b4cd8dc7792aef17918b9704b58e0
diff --git a/app-misc/yq/yq-3.2.1.ebuild b/app-misc/yq/yq-3.2.1.ebuild
new file mode 100644
index 000000000000..01b7d551cff6
--- /dev/null
+++ b/app-misc/yq/yq-3.2.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit pypi distutils-r1
+
+DESCRIPTION="Command-line YAML processor - jq wrapper for YAML documents"
+HOMEPAGE="
+	https://yq.readthedocs.io/
+	https://github.com/kislyuk/yq/
+	https://pypi.org/project/yq/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-misc/jq
+	dev-python/argcomplete[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	>=dev-python/tomlkit-0.11.6[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/wheel[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/yq-2.13.0-tests.patch"
+)
+
+python_prepare_all() {
+	sed -e 's:unittest.main():unittest.main(verbosity=2):' \
+		-i test/test.py || die
+
+	sed -r -e 's:[[:space:]]*"coverage",:: ; s:[[:space:]]*"flake8",::' \
+		-i setup.py || die
+
+	sed -e '/license_file/ d' -i setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${EPYTHON}" test/test.py </dev/null || die "tests failed under ${EPYTHON}"
+}