net-misc/remmina: add 1.4.33

Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index f3aac640e120..88d63ddd2592 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -2,3 +2,4 @@ DIST Remmina-v1.4.29.tar.bz2 2014832 BLAKE2B a5e3a54d510c74fd8399116dfd1cc67aaaf
 DIST Remmina-v1.4.30.tar.bz2 2026559 BLAKE2B 96b4946e5d9480239f5089369cca6fee7bbe9129bb87f685d849df745cef7eca5b20cd8053ec3250378c1ca2be34e1b3c40d463a45c655aca65a73e9ac018593 SHA512 4e2beb4fd27bd9060a95735bd43ee80260d036bb59c406aa0d9ef63fcbd04c6e358384416b2308367d88a1f87d6e1af42299a21d59fd06dce785b9cfe1b67c84
 DIST Remmina-v1.4.31.tar.bz2 2078380 BLAKE2B daee0b68305e3ec0eedcc8cb3622ed5649303562fccd766bf5cc6ed1e96f27c1608286afa1b9bbaf44480bdc210f71a863bf442974ebbc1c50ebfbcf2dfeea35 SHA512 288e7fb5b5251d251e9502ec310f2bfe526f1a28a91c9dd9e79c712191c5d2b287844bd994596dc5097ec50ed8282d0af11144f6c5f0a74cb444aa4c6a8f6838
 DIST Remmina-v1.4.32.tar.bz2 2096310 BLAKE2B 2b625e8dc79c4942093c141acc6c256dce4067176422552abafdecc3d933d3196a50023632de56b1036e0f4d740a9601e1367431899da63a8fb463d5ab58f6d4 SHA512 ad5289b63038846d96ca193c37b266b19e15dbd0f513ce8cea936a81cdbb6b7476c465657944938c34695cb3ff16ade81b4a7ed37c3ab08257537b121c2ad7e9
+DIST Remmina-v1.4.33.tar.bz2 2105164 BLAKE2B 94f73f895f7e0478779d71097ee57ba049299e702527df2cf8a48ea41647f641684131b10b2f4faa7cf831ccea29611a68c2427127a2ebea87acac54f996a446 SHA512 c019131d2c3756946a332a3037286c8370a2e07b20a416c657cc2852ece9e59236499a2c5e45d4e9f391d9265089763957c6968c668e110c350e668053db6d82
diff --git a/net-misc/remmina/remmina-1.4.33.ebuild b/net-misc/remmina/remmina-1.4.33.ebuild
new file mode 100644
index 000000000000..746d4ed7bccc
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.33.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cmake optfeature python-single-r1 xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v.${PV}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+appindicator crypt cups examples keyring gvnc kwallet nls python spice ssh rdp vnc wayland webkit zeroconf"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3[wayland?]
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	appindicator? ( dev-libs/libayatana-appindicator )
+	crypt? ( dev-libs/libgcrypt:0= )
+	keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet )
+	python? ( ${PYTHON_DEPS} )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4.1 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	spice? ( app-emulation/spice-protocol )
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${PN^}-v.${PV}-2c4e1479433e51418ecb6089f35182bfebc5b57e"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	PATCHES+=( ${FILESDIR}/${PN}-1.4.32-REM-2981.patch ) #914851
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DHAVE_LIBAPPINDICATOR=$(usex appindicator ON OFF)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=OFF
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_LIBSECRET=$(usex keyring)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_PYTHONLIBS=$(usex python ON OFF)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_X2GO=OFF
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+}