media-plugins/grilo-plugins: Version bump to 0.3.16

Closes: https://bugs.gentoo.org/877417
Closes: https://github.com/gentoo/gentoo/pull/30117
Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/media-plugins/grilo-plugins/Manifest b/media-plugins/grilo-plugins/Manifest
index e1339c7d7d80..0710053d83b4 100644
--- a/media-plugins/grilo-plugins/Manifest
+++ b/media-plugins/grilo-plugins/Manifest
@@ -1 +1,2 @@
 DIST grilo-plugins-0.3.15.tar.xz 1844584 BLAKE2B dbd25dd79e1676c42e5d36e6253628d7940ef75d1ba7625f5ffc36ad80f44ea0bc61a4beab609be26dc4c2c3f1fbc4f74905064dcb3df8a690cf67a4da2348b3 SHA512 4580990aeea6028668cf1762e8541a13349064e2713d97749126ea4a459e0c590b93a19c0f138103233a8fb7ab1c5009df1473c65ed06dce78e26c24aa63c2db
+DIST grilo-plugins-0.3.16.tar.xz 1843572 BLAKE2B 08f7af1a24f1f86019a3adf2ceea0bbca068f61db5e6e508b7f91f1b864ef3d788fdca7329c464c1a3197f0ca4c6efd5b4b0d84afd688dcb99a54ba1d958056a SHA512 ce1f2786af24ebac98a1dac455f91fa7f63eefcf9029872a8ca1d631bf4fcf76f0578e68e00da20fbfe4c0aeac285ccf9a3e1a8301ffa623a45dbb0b75cb2a32
diff --git a/media-plugins/grilo-plugins/grilo-plugins-0.3.16.ebuild b/media-plugins/grilo-plugins/grilo-plugins-0.3.16.ebuild
new file mode 100644
index 000000000000..966ab7296565
--- /dev/null
+++ b/media-plugins/grilo-plugins/grilo-plugins-0.3.16.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+LUA_COMPAT=( lua5-{3,4} )
+inherit gnome.org lua-single meson xdg
+
+DESCRIPTION="A collection of plugins for the Grilo framework"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="daap chromaprint flickr freebox gnome-online-accounts lua test thetvdb tracker upnp-av +youtube"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
+
+# GOA is only optionally used by lua-factory plugins (checked at v0.3.16)
+# json-glib used by tmdb and lua; tmdb currently non-optional
+# TODO: validate upnp-av dleyna deps
+RDEPEND="
+	>=dev-libs/glib-2.66:2
+	>=media-libs/grilo-0.3.15-r1:${SLOT}=[playlist]
+	freebox? ( net-dns/avahi[dbus] )
+	>=dev-libs/gom-0.4
+	chromaprint? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-plugins/gst-plugins-chromaprint:1.0
+	)
+	dev-libs/json-glib
+	daap? ( >=net-libs/libdmapsharing-3.9.11:4.0= )
+	media-libs/libmediaart:2.0
+	net-libs/libsoup:3.0
+	dev-libs/libxml2:2
+	flickr? ( net-libs/liboauth )
+	dev-db/sqlite:3
+	>=dev-libs/totem-pl-parser-3.4.1:=
+	tracker? ( app-misc/tracker:3= )
+	upnp-av? ( net-libs/dleyna:1.0= )
+	lua? (
+		${LUA_DEPS}
+		app-arch/libarchive
+		dev-libs/libxml2:2
+		gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.17.91:= )
+	)
+	thetvdb? ( app-arch/libarchive )
+	youtube? ( >=dev-libs/libgdata-0.17.0:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.5
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	upnp-av? ( >=dev-util/gdbus-codegen-2.44 )
+	virtual/pkgconfig
+	lua? ( dev-util/gperf )
+"
+
+pkg_pretend() {
+	if use gnome-online-accounts; then
+		if ! use lua; then
+			ewarn "Ignoring USE=gnome-online-accounts USE does not contain lua"
+		fi
+	fi
+}
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	sed -i -e "s:'GETTEXT_PACKAGE', meson.project_name():'GETTEXT_PACKAGE', 'grilo-plugins-${SLOT%/*}':" meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-plugins-${SLOT%/*}':" po/meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-plugins-${SLOT%/*}':" help/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable-bookmarks=yes
+		-Denable-chromaprint=$(usex chromaprint yes no)
+		-Denable-dleyna=$(usex upnp-av yes no)
+		-Denable-dmap=$(usex daap yes no)
+		-Denable-filesystem=yes
+		-Denable-flickr=$(usex flickr yes no)
+		-Denable-freebox=$(usex freebox yes no)
+		-Denable-gravatar=yes
+		-Denable-local-metadata=yes
+		-Denable-lua-factory=$(usex lua yes no)
+		-Denable-magnatune=yes
+		-Denable-metadata-store=yes
+		-Denable-opensubtitles=no # Requires libsoup-2
+		-Denable-optical-media=yes
+		-Denable-podcasts=yes
+		-Denable-raitv=yes
+		-Denable-shoutcast=yes
+		-Denable-thetvdb=$(usex thetvdb yes no)
+		-Denable-tmdb=yes
+		-Denable-tracker=no
+		-Denable-tracker3=$(usex tracker yes no)
+		-Denable-youtube=$(usex youtube yes no)
+		-Dhelp=no
+	)
+	if use lua; then
+		emesonargs+=($(meson_feature gnome-online-accounts goa))
+	else
+		emesonargs+=(-Dgoa=disabled)
+	fi
+	meson_src_configure
+}