dev-util/sysdig-kmod: EAPI7->8, migrate to linux-mod-r1

Affected with incompatible-pointer-types issues with tested
kernel 6.3.4 (regardless of migration), but is fine with LTS.

Lazy KCFLAGS=-Wno-error=incompatible-pointer-types *could* be
used as a (bad) temporary fix, but I'd rather not without trying
runtime.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 36 insertions, 49 deletions

diff --git a/dev-util/sysdig-kmod/sysdig-kmod-0.27.1-r1.ebuild b/dev-util/sysdig-kmod/sysdig-kmod-0.27.1-r1.ebuild
new file mode 100644
index 000000000000..b08faed2f3e3
--- /dev/null
+++ b/dev-util/sysdig-kmod/sysdig-kmod-0.27.1-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake linux-mod-r1
+
+MY_P=${P/-kmod}
+DESCRIPTION="Kernel module for dev-util/sysdig"
+HOMEPAGE="https://sysdig.com/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="|| ( MIT GPL-2 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+PATCHES=(
+	"${FILESDIR}"/${PV}-fix-kmod-build-on-5.18+.patch
+)
+
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# cmake is only used to generate the Makefile for modules
+	sed -i '/USE_BUNDLED_DEPS/,$d' CMakeLists.txt || die
+}
+
+src_compile() {
+	local modlist=( sysdig-probe=:"${BUILD_DIR}"/driver/src )
+	local modargs=( KERNELDIR="${KV_OUT_DIR}" )
+
+	linux-mod-r1_src_compile
+}
diff --git a/dev-util/sysdig-kmod/sysdig-kmod-0.27.1.ebuild b/dev-util/sysdig-kmod/sysdig-kmod-0.27.1.ebuild
deleted file mode 100644
index b679552f204c..000000000000
--- a/dev-util/sysdig-kmod/sysdig-kmod-0.27.1.ebuild
+++ /dev/null
@@ -1,49 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit cmake linux-mod
-
-MY_P=${P/-kmod}
-DESCRIPTION="Kernel module for dev-util/sysdig"
-HOMEPAGE="https://sysdig.com/"
-SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="|| ( MIT GPL-2 )"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="!<=dev-util/sysdig-0.26.4[modules]"
-
-CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
-
-PATCHES=( "${FILESDIR}"/${PV}-fix-kmod-build-on-5.18+.patch )
-
-pkg_pretend() {
-	linux-mod_pkg_setup
-}
-
-pkg_setup() {
-	linux-mod_pkg_setup
-}
-
-src_prepare() {
-	sed -i -e '/USE_BUNDLED_DEPS/,$d' CMakeLists.txt || die
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		# we will use linux-mod for that
-		-DBUILD_DRIVER=OFF
-	)
-
-	cmake_src_configure
-
-	# setup linux-mod ugliness
-	MODULE_NAMES="sysdig-probe(extra:${BUILD_DIR}/driver/src:)"
-	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
-	BUILD_TARGETS="all"
-}