dev-libs/libgusb: version bump 0.2.9 → 0.2.11

Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-libs/libgusb/libgusb-0.2.11.ebuild b/dev-libs/libgusb/libgusb-0.2.11.ebuild
new file mode 100644
index 000000000000..aca94f3692bc
--- /dev/null
+++ b/dev-libs/libgusb/libgusb-0.2.11.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils gnome2 multilib-minimal vala
+
+DESCRIPTION="GObject wrapper for libusb"
+HOMEPAGE="https://github.com/hughsie/libgusb"
+SRC_URI="https://people.freedesktop.org/~hughsient/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="+introspection static-libs vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2[${MULTILIB_USEDEP}]
+	virtual/libusb:1[udev,${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.29:= )
+"
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	dev-util/gtk-doc-am
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	vala? ( $(vala_depend) )
+"
+
+# Tests try to access usb devices in /dev
+RESTRICT="test"
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable static-libs static) \
+		$(multilib_native_use_enable vala)
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/api/html docs/api/html || die
+	fi
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}