# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit webapp eutils depend.php

MY_P=${P/webaccess-/}

DESCRIPTION="Open Source Groupware Solution"
HOMEPAGE="http://zarafa.com/"
SRC_URI="http://dev.gentoo.org/~dagger/files/${MY_P}.tar.bz2"

LICENSE="AGPL-3"
KEYWORDS="~x86 ~amd64"
IUSE=""

need_php_httpd

S="${WORKDIR}"/${MY_P}/php-webclient-ajax

RDEPEND=">=dev-libs/libical-0.40"
DEPEND="${RDEPEND}"

pkg_setup () {
	webapp_pkg_setup
	require_php_with_use iconv session xml
}

src_install() {
	webapp_src_preinst

	# make .po files
	for pofile in "${S}"/server/language/*/LC_MESSAGES/zarafa.po; do
		msgfmt -o ${pofile%%.po}.mo ${pofile}
		rm ${pofile}
	done

	dodir /var/lib/zarafa-webaccess/plugins
	dodir /var/lib/zarafa-webaccess/tmp
	dosym /var/lib/zarafa-webaccess/plugins "${MY_HTDOCSDIR}"/plugins

	# remove unneeded files
	rm zarafa-webaccess.conf

	cp "${S}"/config.php.dist "${S}"/config.php
	insinto "${MY_HTDOCSDIR}"
	doins -r "${S}"/*

	webapp_configfile "${MY_HTDOCSDIR}"/config.php
	webapp_serverowned "${MY_HTDOCSDIR}"/config.php

	webapp_src_install
}