games-roguelike/zangband/zangband-2.7.4b.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-roguelike/zangband/zangband-2.7.4b.ebuild,v 1.4 2006/11/05 01:31:22 nyhm Exp $

inherit games

DESCRIPTION="An enhanced version of the Roguelike game Angband"
HOMEPAGE="http://www.zangband.org/"
SRC_URI="ftp://clockwork.dementia.org/angband/Variant/ZAngband/${P}.tar.gz"

LICENSE="Moria"
SLOT="0"
KEYWORDS="x86 ppc"
IUSE="gtk tk"

# Dropping X use keyword: 
#  it had to be $(use_with X x11)
#  but ebuild fails to link without-x11
RDEPEND=">=sys-libs/ncurses-5
	sys-libs/zlib
	tk? (
		dev-lang/tcl
		dev-lang/tk
	)
	gtk? ( =x11-libs/gtk+-1* )
	|| ( x11-libs/libXaw virtual/x11 )"
DEPEND="${RDEPEND}
	|| ( x11-proto/xextproto virtual/x11 )"

S="${WORKDIR}/${PN}"

src_compile() {
	egamesconf \
		--datadir="${GAMES_DATADIR_BASE}" \
		"--with-setgid=${GAMES_GROUP}" \
		`use_with gtk` \
		`use_with tk tcltk` \
		|| die "configure failed"
	emake || die "emake failed"
}

src_install() {
	# Keep some important dirs we want to chmod later
	keepdir ${GAMES_DATADIR}/zangband/lib/apex \
		${GAMES_DATADIR}/zangband/lib/user \
		${GAMES_DATADIR}/zangband/lib/save

	# Install the basic files but remove unneeded crap
	make DESTDIR=${D}/${GAMES_DATADIR}/zangband/ installbase || \
		die "make installbase failed"
	rm ${D}${GAMES_DATADIR}/zangband/{angdos.cfg,readme,z_faq.txt,z_update.txt}

	# Install everything else and fix the permissions
	dogamesbin zangband                 || die "dogamesbin failed"
	dodoc readme z_faq.txt z_update.txt || die "dodoc failed"
	find "${D}${GAMES_DATADIR}/zangband/lib" -type f -exec chmod a-x \{\} \;

	prepgamesdirs
	# All users in the games group need write permissions to some important dirs
	chmod -R g+w ${D}/${GAMES_DATADIR}/zangband/lib/{apex,save,user}
}