From 5dd394e8315064cdf2dd05366b97bd83367544b5 Mon Sep 17 00:00:00 2001
From: Mike Frysinger <vapier@gentoo.org>
Date: Mon, 20 May 2013 17:55:21 +0000
Subject: Version bump.

(Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)
---
 sys-apps/acl/ChangeLog         |  7 ++++-
 sys-apps/acl/acl-2.2.52.ebuild | 58 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+), 1 deletion(-)
 create mode 100644 sys-apps/acl/acl-2.2.52.ebuild

(limited to 'sys-apps/acl')

diff --git a/sys-apps/acl/ChangeLog b/sys-apps/acl/ChangeLog
index 6f298ddf4f7d..37fddc709b27 100644
--- a/sys-apps/acl/ChangeLog
+++ b/sys-apps/acl/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/acl
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/acl/ChangeLog,v 1.119 2013/02/19 05:08:46 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/acl/ChangeLog,v 1.120 2013/05/20 17:55:21 vapier Exp $
+
+*acl-2.2.52 (20 May 2013)
+
+  20 May 2013; Mike Frysinger <vapier@gentoo.org> +acl-2.2.52.ebuild:
+  Version bump.
 
   19 Feb 2013; Zac Medico <zmedico@gentoo.org> acl-2.2.51.ebuild:
   Add ~arm-linux keyword.
diff --git a/sys-apps/acl/acl-2.2.52.ebuild b/sys-apps/acl/acl-2.2.52.ebuild
new file mode 100644
index 000000000000..6736ac934688
--- /dev/null
+++ b/sys-apps/acl/acl-2.2.52.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/acl/acl-2.2.52.ebuild,v 1.1 2013/05/20 17:55:21 vapier Exp $
+
+EAPI="4"
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="access control list utilities, libraries and headers"
+HOMEPAGE="http://savannah.nongnu.org/projects/acl"
+SRC_URI="http://download.savannah.gnu.org/releases/${PN}/${P}.src.tar.gz
+	nfs? ( http://www.citi.umich.edu/projects/nfsv4/linux/acl-patches/2.2.42-2/acl-2.2.42-CITI_NFS4_ALL-2.dif )"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux"
+IUSE="nfs nls static-libs"
+
+RDEPEND=">=sys-apps/attr-2.4
+	nfs? ( net-libs/libnfsidmap )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	if use nfs ; then
+		cp "${DISTDIR}"/acl-2.2.42-CITI_NFS4_ALL-2.dif . || die
+		sed -i \
+			-e '/^diff --git a.debian.changelog b.debian.changelog/,/^diff --git/d' \
+			acl-2.2.42-CITI_NFS4_ALL-2.dif || die
+		epatch acl-2.2.42-CITI_NFS4_ALL-2.dif
+	fi
+	sed -i \
+		-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
+		-e '/HAVE_ZIPPED_MANPAGES/s:=.*:=false:' \
+		include/builddefs.in \
+		|| die
+	strip-linguas po
+}
+
+src_configure() {
+	unset PLATFORM #184564
+	export OPTIMIZER=${CFLAGS}
+	export DEBUG=-DNDEBUG
+
+	econf \
+		$(use_enable nls gettext) \
+		--enable-shared $(use_enable static-libs static) \
+		--libexecdir="${EPREFIX}"/usr/$(get_libdir) \
+		--bindir="${EPREFIX}"/bin
+}
+
+src_install() {
+	emake DIST_ROOT="${D}" install install-dev install-lib || die
+	use static-libs || find "${ED}" -name '*.la' -delete
+
+	# move shared libs to /
+	gen_usr_ldscript -a acl
+}
-- 
cgit v1.2.3-65-gdbad