From d981dae79ec48249e8d7be18ee2001a0a9c7496c Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Fri, 13 Jun 2014 08:21:23 +0000
Subject: Enable multilib support, needed for media-libs/libmetalink.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)
---
 dev-util/cunit/ChangeLog              |  9 ++++--
 dev-util/cunit/cunit-2.1_p2-r1.ebuild | 55 +++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+), 2 deletions(-)
 create mode 100644 dev-util/cunit/cunit-2.1_p2-r1.ebuild

(limited to 'dev-util/cunit')

diff --git a/dev-util/cunit/ChangeLog b/dev-util/cunit/ChangeLog
index b82ef098672f..d80ea7222986 100644
--- a/dev-util/cunit/ChangeLog
+++ b/dev-util/cunit/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/cunit
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/cunit/ChangeLog,v 1.39 2013/10/09 19:44:40 hasufell Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/cunit/ChangeLog,v 1.40 2014/06/13 08:21:23 mgorny Exp $
+
+*cunit-2.1_p2-r1 (13 Jun 2014)
+
+  13 Jun 2014; Michał Górny <mgorny@gentoo.org> +cunit-2.1_p2-r1.ebuild:
+  Enable multilib support, needed for media-libs/libmetalink.
 
   09 Oct 2013; Julian Ospald <hasufell@gentoo.org> cunit-2.1_p2.ebuild:
   link to ncurses explicitly to avoid breaking reverse deps
diff --git a/dev-util/cunit/cunit-2.1_p2-r1.ebuild b/dev-util/cunit/cunit-2.1_p2-r1.ebuild
new file mode 100644
index 000000000000..8c4420f321c3
--- /dev/null
+++ b/dev-util/cunit/cunit-2.1_p2-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/cunit/cunit-2.1_p2-r1.ebuild,v 1.1 2014/06/13 08:21:23 mgorny Exp $
+
+EAPI=5
+inherit autotools eutils flag-o-matic multilib-minimal toolchain-funcs
+
+MY_PN='CUnit'
+MY_PV="${PV/_p*}-2"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="CUnit - C Unit Test Framework"
+SRC_URI="mirror://sourceforge/cunit/${MY_P}-src.tar.bz2"
+HOMEPAGE="http://cunit.sourceforge.net"
+
+SLOT="0"
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="ncurses static-libs"
+
+RDEPEND="ncurses? ( sys-libs/ncurses[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS NEWS README ChangeLog )
+
+src_prepare() {
+	sed -e "/^docdir/d" -i doc/Makefile.am || die
+	sed -e '/^dochdrdir/{s:$(prefix)/doc/@PACKAGE@:$(docdir):}' \
+		-i doc/headers/Makefile.am || die
+	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.in || die
+	eautoreconf
+
+	append-cppflags -D_BSD_SOURCE
+
+	# unable to find headers otherwise
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local LIBS=${LIBS}
+	append-libs $($(tc-getPKG_CONFIG) --libs ncurses)
+
+	econf \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable static-libs static) \
+		--disable-debug \
+		$(use_enable ncurses curses)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}
-- 
cgit v1.2.3-65-gdbad