1 files changed, 53 insertions, 0 deletions
diff --git a/net-analyzer/nmap/nmap-5.21.ebuild b/net-analyzer/nmap/nmap-5.21.ebuild
new file mode 100644
index 000000000000..142dc54eaba3
--- /dev/null
+++ b/net-analyzer/nmap/nmap-5.21.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-5.21.ebuild,v 1.1 2010/01/29 23:20:38 spock Exp $
+
+EAPI="2"
+
+inherit eutils flag-o-matic
+
+MY_P=${P/_beta/BETA}
+
+DESCRIPTION="A utility for network exploration or security auditing"
+HOMEPAGE="http://nmap.org/"
+SRC_URI="http://download.insecure.org/nmap/dist/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="gtk lua ssl"
+
+DEPEND="dev-libs/libpcre
+	net-libs/libpcap
+	gtk? ( >=x11-libs/gtk+-2.6
+		   >=dev-python/pygtk-2.6
+		   || ( >=dev-lang/python-2.5[sqlite]
+				>=dev-python/pysqlite-2 )
+		 )
+	lua? ( >=dev-lang/lua-5.1.4-r1[deprecated] )
+	ssl? ( dev-libs/openssl )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-4.75-include.patch"
+	epatch "${FILESDIR}/${PN}-4.75-nolua.patch"
+	epatch "${FILESDIR}/${PN}-5.10_beta1-string.patch"
+	sed -i -e 's/-m 755 -s ncat/-m 755 ncat/' ncat/Makefile.in
+}
+
+src_configure() {
+	# The bundled libdnet is incompatible with the version available in the
+	# tree, so we cannot use the system library here.
+	econf --with-libdnet=included \
+		$(use_with gtk zenmap) \
+		$(use_with lua liblua) \
+		$(use_with ssl openssl)
+}
+
+src_install() {
+	LC_ALL=C emake DESTDIR="${D}" -j1 STRIP=: nmapdatadir=/usr/share/nmap install || die
+	dodoc CHANGELOG HACKING docs/README docs/*.txt || die
+
+	use gtk && doicon "${FILESDIR}/nmap-logo-64.png"
+}