2 files changed, 89 insertions, 1 deletions
diff --git a/games-engines/scummvm/ChangeLog b/games-engines/scummvm/ChangeLog
index ee602a6c5d3e..e07a2fd006f7 100644
--- a/games-engines/scummvm/ChangeLog
+++ b/games-engines/scummvm/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-engines/scummvm
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/ChangeLog,v 1.104 2011/05/31 17:47:22 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/ChangeLog,v 1.105 2011/07/16 08:05:22 mr_bones_ Exp $
+
+*scummvm-1.3.1 (16 Jul 2011)
+
+  16 Jul 2011; Michael Sterrett <mr_bones_@gentoo.org> +scummvm-1.3.1.ebuild:
+  version bump
 
 *scummvm-1.3.0 (31 May 2011)
 
diff --git a/games-engines/scummvm/scummvm-1.3.1.ebuild b/games-engines/scummvm/scummvm-1.3.1.ebuild
new file mode 100644
index 000000000000..9f61074f68f5
--- /dev/null
+++ b/games-engines/scummvm/scummvm-1.3.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/scummvm-1.3.1.ebuild,v 1.1 2011/07/16 08:05:22 mr_bones_ Exp $
+
+EAPI=2
+inherit eutils flag-o-matic games
+
+DESCRIPTION="Reimplementation of the SCUMM game engine used in Lucasarts adventures"
+HOMEPAGE="http://scummvm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/scummvm/${P/_/}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="alsa debug flac fluidsynth mp3 ogg vorbis"
+RESTRICT="test"  # it only looks like there's a test there #77507
+
+RDEPEND=">=media-libs/libsdl-1.2.2[audio,joystick,video]
+	>media-libs/libmpeg2-0.3.1
+	sys-libs/zlib
+	ogg? ( media-libs/libogg media-libs/libvorbis )
+	vorbis? ( media-libs/libogg media-libs/libvorbis )
+	alsa? ( media-libs/alsa-lib )
+	mp3? ( media-libs/libmad )
+	flac? ( media-libs/flac )
+	fluidsynth? ( media-sound/fluidsynth )"
+DEPEND="${RDEPEND}
+	x86? ( dev-lang/nasm )"
+
+S=${WORKDIR}/${P/_/}
+
+src_prepare() {
+	# -g isn't needed for nasm here
+	sed -i \
+		-e '/NASMFLAGS/ s/-g//' \
+		configure || die
+	sed -i \
+		-e '/INSTALL.*doc/d' \
+		-e '/INSTALL.*\/pixmaps/d' \
+		-e 's/-s //' \
+		ports.mk || die
+}
+
+src_configure() {
+	local myconf
+
+	if use vorbis || use ogg ; then
+		myconf="${myconf} --enable-vorbis"
+	else
+		myconf="${myconf} --disable-vorbis"
+	fi
+
+	# bug #137547
+	use fluidsynth || myconf="${myconf} --disable-fluidsynth"
+
+	use x86 && append-ldflags -Wl,-z,noexecstack
+
+	# NOT AN AUTOCONF SCRIPT SO DONT CALL ECONF
+	# mpeg2 support needs vorbis (bug #79149) so turn it off if -oggvorbis
+	./configure \
+		--backend=sdl \
+		--host=$CHOST \
+		--enable-verbose-build \
+		--prefix=/usr \
+		--bindir="${GAMES_BINDIR}" \
+		--datadir="${GAMES_DATADIR}"/${PN} \
+		--libdir="${GAMES_LIBDIR}" \
+		--enable-zlib \
+		$(use_enable debug) \
+		$(use_enable alsa) \
+		$(use_enable mp3 mad) \
+		$(use_enable flac) \
+		$(use_enable x86 nasm) \
+		${myconf} || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS NEWS README TODO
+	doicon icons/scummvm.svg
+	make_desktop_entry scummvm ScummVM scummvm "Game;AdventureGame"
+	prepgamesdirs
+}