bup

fixing bug 442418
fixing bug 499204

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x2471eb3e40ac5ac3)

6 files changed, 216 insertions, 5 deletions

diff --git a/media-tv/tvheadend/ChangeLog b/media-tv/tvheadend/ChangeLog
index dc6c28a69e04..ef2666804a7b 100644
--- a/media-tv/tvheadend/ChangeLog
+++ b/media-tv/tvheadend/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-tv/tvheadend
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/tvheadend/ChangeLog,v 1.4 2012/10/27 06:09:17 yngwin Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/tvheadend/ChangeLog,v 1.5 2014/06/21 21:15:09 prometheanfire Exp $
+
+*tvheadend-3.4.27 (21 Jun 2014)
+*tvheadend-9999 (21 Jun 2014)
+
+  21 Jun 2014; Matthew Thode <prometheanfire@gentoo.org>
+  +files/tvheadend.service, +tvheadend-3.4.27.ebuild, +tvheadend-9999.ebuild,
+  metadata.xml, tvheadend-3.2.ebuild:
+  bup  fixing bug 442418 fixing bug 499204
 
 *tvheadend-3.2 (27 Oct 2012)
 
diff --git a/media-tv/tvheadend/files/tvheadend.service b/media-tv/tvheadend/files/tvheadend.service
new file mode 100644
index 000000000000..227faffcb082
--- /dev/null
+++ b/media-tv/tvheadend/files/tvheadend.service
@@ -0,0 +1,14 @@
+[Unit]
+Description=tvheadend
+After=network.target
+
+[Service]
+Type=forking
+PIDFile=/run/tvheadend.pid
+ExecStart=/usr/bin/tvheadend -f -p /run/tvheadend.pid -C -c /etc/tvheadend -u tvheadend -g video
+ExecStop=/usr/bin/rm /run/tvheadend.pid
+Restart=always
+RestartSec=5
+
+[Install]
+WantedBy=multi-user.target
diff --git a/media-tv/tvheadend/metadata.xml b/media-tv/tvheadend/metadata.xml
index b202becf81ae..e6ede4196eb1 100644
--- a/media-tv/tvheadend/metadata.xml
+++ b/media-tv/tvheadend/metadata.xml
@@ -8,5 +8,9 @@
   </maintainer>
   <use>
     <flag name='xmltv'>Use <pkg>media-tv/xmltv</pkg></flag>
+    <flag name='ccache'>Use <pkg>dev-util/ccache</pkg></flag>
+    <flag name='dvbscan'>Use <pkg>media-tv/linuxtv-dvb-apps</pkg></flag>
+    <flag name='imagecache'>Enable support for image caching</flag>
+    <flag name='uriparser'>Use <pkg>dev-libs/uriparser</pkg></flag>
   </use>
 </pkgmetadata>
diff --git a/media-tv/tvheadend/tvheadend-3.2.ebuild b/media-tv/tvheadend/tvheadend-3.2.ebuild
index 1373db561f8d..d13e5825c328 100644
--- a/media-tv/tvheadend/tvheadend-3.2.ebuild
+++ b/media-tv/tvheadend/tvheadend-3.2.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/tvheadend/tvheadend-3.2.ebuild,v 1.1 2012/10/27 06:09:17 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/tvheadend/tvheadend-3.2.ebuild,v 1.2 2014/06/21 21:15:09 prometheanfire Exp $
 
 EAPI=4
 
@@ -8,7 +8,7 @@ inherit eutils toolchain-funcs user
 
 DESCRIPTION="A combined DVB receiver, Digital Video Recorder and Live TV streaming server"
 HOMEPAGE="https://www.lonelycoder.com/redmine/projects/tvheadend/"
-SRC_URI="https://github.com/downloads/${PN}/${PN}/${P}.tar.gz"
+SRC_URI="mirror://github/tvheadend/tvheadend/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="GPL-3"
 SLOT="0"
diff --git a/media-tv/tvheadend/tvheadend-3.4.27.ebuild b/media-tv/tvheadend/tvheadend-3.4.27.ebuild
new file mode 100644
index 000000000000..0e1c837af939
--- /dev/null
+++ b/media-tv/tvheadend/tvheadend-3.4.27.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/tvheadend/tvheadend-3.4.27.ebuild,v 1.1 2014/06/21 21:15:09 prometheanfire Exp $
+
+EAPI=5
+
+inherit eutils linux-info systemd toolchain-funcs user
+
+MY_PV="3.4patch1"
+
+DESCRIPTION="Tvheadend is a TV streaming server and digital video recorder"
+HOMEPAGE="https://tvheadend.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="avahi ccache curl +dvb +dvbscan ffmpeg imagecache inotify uriparser xmltv zlib"
+
+REQUIRED_USE="
+	dvbscan? ( dvb )
+	imagecache? ( curl )"
+
+DEPEND="dev-libs/openssl
+	avahi? ( net-dns/avahi )
+	ccache? ( dev-util/ccache )
+	curl? ( net-misc/curl )
+	dvb? ( virtual/linuxtv-dvb-headers )
+	ffmpeg? ( virtual/ffmpeg )
+	uriparser? ( dev-libs/uriparser )
+	zlib? ( sys-libs/zlib )"
+
+RDEPEND="${DEPEND}
+	dvb? ( media-tv/linuxtv-dvb-apps )
+	xmltv? ( media-tv/xmltv )"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+CONFIG_CHECK="~INOTIFY_USER"
+
+DOCS=( README )
+
+pkg_setup() {
+	enewuser tvheadend -1 -1 /dev/null video
+}
+
+src_prepare() {
+	# set the version number
+	echo "const char *tvheadend_version = \"${PV}\";" \
+		> src/version.c || die "setting version failed!"
+
+	# remove '-Werror' wrt bug #438424
+	sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
+}
+
+src_configure() {
+	econf --prefix="${EPREFIX}"/usr \
+		--datadir="${EPREFIX}"/usr/share \
+		--mandir="${EPREFIX}"/usr/share/man/man1 \
+		$(use_enable avahi) \
+		$(use_enable ccache) \
+		$(use_enable curl) \
+		--disable-dvbscan \
+		$(use_enable dvb linuxdvb) \
+		$(use_enable ffmpeg libav) \
+		$(use_enable imagecache) \
+		$(use_enable inotify) \
+		$(use_enable uriparser) \
+		$(use_enable zlib)
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}/tvheadend.initd" tvheadend
+	newconfd "${FILESDIR}/tvheadend.confd" tvheadend
+
+	systemd_dounit "${FILESDIR}/tvheadend.service"
+
+	dodir /etc/tvheadend
+	fperms 0700 /etc/tvheadend
+	fowners tvheadend:video /etc/tvheadend
+}
+
+pkg_postinst() {
+	elog "The Tvheadend web interface can be reached at:"
+	elog "http://localhost:9981/"
+	elog
+	elog "Make sure that you change the default username"
+	elog "and password via the Configuration / Access control"
+	elog "tab in the web interface."
+}
diff --git a/media-tv/tvheadend/tvheadend-9999.ebuild b/media-tv/tvheadend/tvheadend-9999.ebuild
new file mode 100644
index 000000000000..e83e5e5359dd
--- /dev/null
+++ b/media-tv/tvheadend/tvheadend-9999.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/tvheadend/tvheadend-9999.ebuild,v 1.1 2014/06/21 21:15:09 prometheanfire Exp $
+
+EAPI=5
+
+inherit eutils git-2 linux-info systemd toolchain-funcs user
+
+DESCRIPTION="Tvheadend is a TV streaming server and digital video recorder"
+HOMEPAGE="https://tvheadend.org/"
+EGIT_REPO_URI="git://github.com/tvheadend/tvheadend.git"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+
+IUSE="avahi ccache curl +dvb +dvbscan ffmpeg imagecache inotify uriparser xmltv zlib"
+
+REQUIRED_USE="
+	dvbscan? ( dvb )
+	imagecache? ( curl )"
+
+DEPEND="dev-libs/openssl
+	avahi? ( net-dns/avahi )
+	ccache? ( dev-util/ccache )
+	curl? ( net-misc/curl )
+	dvb? ( virtual/linuxtv-dvb-headers )
+	ffmpeg? ( virtual/ffmpeg )
+	uriparser? ( dev-libs/uriparser )
+	zlib? ( sys-libs/zlib )"
+
+RDEPEND="${DEPEND}
+	dvbscan? ( media-tv/linuxtv-dvb-apps )
+	xmltv? ( media-tv/xmltv )"
+
+CONFIG_CHECK="~INOTIFY_USER"
+
+DOCS=( README.md )
+
+pkg_setup() {
+	enewuser tvheadend -1 -1 /dev/null video
+}
+
+src_prepare() {
+	# remove '-Werror' wrt bug #438424
+	sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
+}
+
+src_configure() {
+	econf --prefix="${EPREFIX}"/usr \
+		--datadir="${EPREFIX}"/usr/share \
+		$(use_enable avahi) \
+		$(use_enable ccache) \
+		$(use_enable curl) \
+		--disable-dvbscan \
+		$(use_enable dvb linuxdvb) \
+		$(use_enable ffmpeg libav) \
+		$(use_enable imagecache) \
+		$(use_enable inotify) \
+		$(use_enable uriparser) \
+		$(use_enable zlib)
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}/tvheadend.initd" tvheadend
+	newconfd "${FILESDIR}/tvheadend.confd" tvheadend
+
+	systemd_dounit "${FILESDIR}/tvheadend.service"
+
+	dodir /etc/tvheadend
+	fperms 0700 /etc/tvheadend
+	fowners tvheadend:video /etc/tvheadend
+}
+
+pkg_postinst() {
+	elog "The Tvheadend web interface can be reached at:"
+	elog "http://localhost:9981/"
+	elog
+	elog "Make sure that you change the default username"
+	elog "and password via the Configuration / Access control"
+	elog "tab in the web interface."
+}