version bump by urcindalo in bug #548562 and fix documentation also by urcindalo in bug #548574

(Portage version: 2.2.19/cvs/Linux x86_64, signed Manifest commit with key 072AD062)

3 files changed, 159 insertions, 4 deletions

diff --git a/media-gfx/darktable/ChangeLog b/media-gfx/darktable/ChangeLog
index 60a8a2770154..cbb26c94ec25 100644
--- a/media-gfx/darktable/ChangeLog
+++ b/media-gfx/darktable/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-gfx/darktable
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.68 2015/04/26 22:40:11 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.69 2015/05/22 20:41:04 maekke Exp $
+
+*darktable-1.6.6 (22 May 2015)
+
+  22 May 2015; Markus Meier <maekke@gentoo.org> +darktable-1.6.6.ebuild,
+  darktable-9999.ebuild:
+  version bump by urcindalo in bug #548562 and fix documentation also by
+  urcindalo in bug #548574
 
 *darktable-1.6.4 (26 Apr 2015)
 
diff --git a/media-gfx/darktable/darktable-1.6.6.ebuild b/media-gfx/darktable/darktable-1.6.6.ebuild
new file mode 100644
index 000000000000..b2d0c6ade07d
--- /dev/null
+++ b/media-gfx/darktable/darktable-1.6.6.ebuild
@@ -0,0 +1,146 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-1.6.6.ebuild,v 1.1 2015/05/22 20:41:04 maekke Exp $
+
+EAPI=5
+
+inherit cmake-utils flag-o-matic toolchain-funcs gnome2-utils fdo-mime pax-utils eutils
+
+DOC_PV="1.6.0"
+
+DESCRIPTION="A virtual lighttable and darkroom for photographers"
+HOMEPAGE="http://www.darktable.org/"
+SRC_URI="https://github.com/darktable-org/${PN}/releases/download/release-${PV}/${P}.tar.xz
+	doc? ( https://github.com/darktable-org/${PN}/releases/download/release-${DOC_PV}/${PN}-usermanual.pdf -> ${PN}-usermanual-${DOC_PV}.pdf )"
+
+LICENSE="GPL-3 CC-BY-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+LANGS=" ca cs da de el es fr it ja nl pl pt_BR pt_PT ru sq sv uk"
+# TODO add lua once dev-lang/lua-5.2 is unmasked
+IUSE="colord cpu_flags_x86_sse3 doc flickr geo gphoto2 graphicsmagick jpeg2k kde libsecret
+nls opencl openmp openexr pax_kernel +rawspeed +slideshow +squish web-services webp
+${LANGS// / linguas_}"
+
+# sse3 support is required to build darktable
+REQUIRED_USE="cpu_flags_x86_sse3"
+
+CDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.28:2
+	dev-libs/libxml2:2
+	gnome-base/librsvg:2
+	media-gfx/exiv2:0=[xmp]
+	media-libs/lcms:2
+	>=media-libs/lensfun-0.2.3
+	media-libs/libpng:0=
+	media-libs/tiff:0
+	net-misc/curl
+	virtual/jpeg:0
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:2
+	x11-libs/pango
+	colord? ( x11-misc/colord:0= )
+	flickr? ( media-libs/flickcurl )
+	geo? ( net-libs/libsoup:2.4 )
+	gphoto2? ( media-libs/libgphoto2:= )
+	graphicsmagick? ( media-gfx/graphicsmagick )
+	jpeg2k? ( media-libs/openjpeg:0 )
+	libsecret? (
+		>=app-crypt/libsecret-0.18
+		dev-libs/json-glib
+	)
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	slideshow? (
+		media-libs/libsdl
+		virtual/glu
+		virtual/opengl
+	)
+	web-services? ( dev-libs/json-glib )
+	webp? ( media-libs/libwebp:0= )"
+RDEPEND="${CDEPEND}
+	x11-themes/gtk-engines:2
+	kde? ( kde-base/kwalletd )"
+DEPEND="${CDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	use cpu_flags_x86_sse3 && append-flags -msse3
+
+	sed -e "s:\(/share/doc/\)darktable:\1${PF}:" \
+		-e "s:\(\${SHARE_INSTALL}/doc/\)darktable:\1${PF}:" \
+		-e "s:LICENSE::" \
+		-i doc/CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_use colord COLORD)
+		$(cmake-utils_use_use flickr FLICKR)
+		$(cmake-utils_use_use geo GEO)
+		$(cmake-utils_use_use gphoto2 CAMERA_SUPPORT)
+		$(cmake-utils_use_use graphicsmagick GRAPHICSMAGICK)
+		$(cmake-utils_use_use jpeg2k OPENJPEG)
+		$(cmake-utils_use_use kde KWALLET)
+		$(cmake-utils_use_use libsecret LIBSECRET)
+		$(cmake-utils_use_use libsecret GLIBJSON)
+		$(cmake-utils_use_use nls NLS)
+		$(cmake-utils_use_use opencl OPENCL)
+		$(cmake-utils_use_use openexr OPENEXR)
+		$(cmake-utils_use_use openmp OPENMP)
+		$(cmake-utils_use !rawspeed DONT_USE_RAWSPEED)
+		$(cmake-utils_use_use squish SQUISH)
+		$(cmake-utils_use_build slideshow SLIDESHOW)
+		$(cmake-utils_use_use web-services GLIBJSON)
+		$(cmake-utils_use_use webp WEBP)
+		-DUSE_LUA=OFF
+		-DCUSTOM_CFLAGS=ON
+		-DINSTALL_IOP_EXPERIMENTAL=ON
+		-DINSTALL_IOP_LEGACY=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	use doc && dodoc "${DISTDIR}"/${PN}-usermanual-${DOC_PV}.pdf
+
+	for lang in ${LANGS} ; do
+		use linguas_${lang} || rm -r "${ED}"/usr/share/locale/${lang}
+	done
+
+	if use pax_kernel && use opencl ; then
+		pax-mark Cm "${ED}"/usr/bin/${PN} || die
+		eqawarn "USE=pax_kernel is set meaning that ${PN} will be run"
+		eqawarn "under a PaX enabled kernel. To do so, the ${PN} binary"
+		eqawarn "must be modified and this *may* lead to breakage! If"
+		eqawarn "you suspect that ${PN} is broken by this modification,"
+		eqawarn "please open a bug."
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
diff --git a/media-gfx/darktable/darktable-9999.ebuild b/media-gfx/darktable/darktable-9999.ebuild
index 4a45fba54ee6..744d7e6f4b4a 100644
--- a/media-gfx/darktable/darktable-9999.ebuild
+++ b/media-gfx/darktable/darktable-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild,v 1.18 2015/02/07 02:38:12 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild,v 1.19 2015/05/22 20:41:04 maekke Exp $
 
 EAPI=5
 
@@ -13,7 +13,8 @@ HOMEPAGE="http://www.darktable.org/"
 
 LICENSE="GPL-3 CC-BY-3.0"
 SLOT="0"
-LANGS=" cs da de el es fr it ja nl pl pt_BR pt_PT ru sq sv uk"
+#KEYWORDS="~amd64 ~x86"
+LANGS=" ca cs da de el es fr it ja nl pl pt_BR pt_PT ru sq sv uk"
 # TODO add lua once dev-lang/lua-5.2 is unmasked
 IUSE="colord cpu_flags_x86_sse3 doc flickr geo gphoto2 graphicsmagick jpeg2k kde libsecret
 nls opencl openmp openexr pax_kernel +rawspeed +slideshow +squish web-services webp
@@ -33,7 +34,7 @@ CDEPEND="
 	media-libs/libpng:0=
 	media-libs/tiff:0
 	net-misc/curl
-	virtual/jpeg
+	virtual/jpeg:0
 	x11-libs/cairo
 	x11-libs/gdk-pixbuf:2
 	x11-libs/gtk+:2
@@ -75,6 +76,7 @@ src_prepare() {
 	use cpu_flags_x86_sse3 && append-flags -msse3
 
 	sed -e "s:\(/share/doc/\)darktable:\1${PF}:" \
+		-e "s:\(\${SHARE_INSTALL}/doc/\)darktable:\1${PF}:" \
 		-e "s:LICENSE::" \
 		-i doc/CMakeLists.txt || die