Bump to 2.24.2. Restored translation of logout dialog and fix bug #249514 and #249847.

(Portage version: 2.2_rc18/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

2 files changed, 96 insertions, 1 deletions

diff --git a/gnome-base/gnome-panel/ChangeLog b/gnome-base/gnome-panel/ChangeLog
index 712c2870bde2..30f612a91112 100644
--- a/gnome-base/gnome-panel/ChangeLog
+++ b/gnome-base/gnome-panel/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-base/gnome-panel
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.262 2008/11/24 15:06:40 leio Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.263 2008/12/21 22:43:22 eva Exp $
+
+*gnome-panel-2.24.2 (21 Dec 2008)
+
+  21 Dec 2008; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-panel-2.24.2.ebuild:
+  Bump to 2.24.2. Restored translation of logout dialog and fix bug #249514
+  and #249847.
 
   24 Nov 2008; Mart Raudsepp <leio@gentoo.org> gnome-panel-2.24.1-r1.ebuild:
   Fix tests
diff --git a/gnome-base/gnome-panel/gnome-panel-2.24.2.ebuild b/gnome-base/gnome-panel/gnome-panel-2.24.2.ebuild
new file mode 100644
index 000000000000..c747df3c62f7
--- /dev/null
+++ b/gnome-base/gnome-panel/gnome-panel-2.24.2.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.24.2.ebuild,v 1.1 2008/12/21 22:43:22 eva Exp $
+
+GCONF_DEBUG="no"
+
+inherit autotools gnome2
+
+DESCRIPTION="The GNOME panel"
+HOMEPAGE="http://www.gnome.org/"
+SRC_URI="${SRC_URI}
+	mirror://gentoo/${PN}-2.24.1-logout+po.tar.bz2"
+
+LICENSE="GPL-2 FDL-1.1 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc eds networkmanager"
+
+RDEPEND=">=gnome-base/gnome-desktop-2.12
+	>=x11-libs/pango-1.15.4
+	>=dev-libs/glib-2.16.0
+	>=x11-libs/gtk+-2.13.1
+	>=dev-libs/libgweather-2.24.1
+	dev-libs/libxml2
+	>=gnome-base/libglade-2.5
+	>=gnome-base/libgnome-2.13
+	>=gnome-base/libgnomeui-2.5.4
+	>=gnome-base/libbonoboui-2.1.1
+	>=gnome-base/orbit-2.4
+	>=x11-libs/libwnck-2.19.5
+	>=gnome-base/gconf-2.6.1
+	>=gnome-base/gnome-menus-2.11.1
+	>=gnome-base/libbonobo-2
+	gnome-base/librsvg
+	>=dev-libs/dbus-glib-0.71
+	>=sys-apps/dbus-1.1.2
+	x11-libs/libXau
+	>=x11-libs/cairo-1.0.0
+	eds? ( >=gnome-extra/evolution-data-server-1.6 )
+	networkmanager? ( >=net-misc/networkmanager-0.6 )"
+DEPEND="${RDEPEND}
+	app-text/scrollkeeper
+	>=app-text/gnome-doc-utils-0.3.2
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.40
+	~app-text/docbook-xml-dtd-4.1.2
+	>=dev-util/gtk-doc-am-1
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog HACKING NEWS README"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		--disable-schemas-install
+		--with-in-process-applets=clock,notification-area,wncklet
+		--disable-polkit
+		$(use_enable networkmanager network-manager)
+		$(use_enable eds)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# Allow logout/shutdown without gnome-session 2.24, bug #246170
+	epatch "${WORKDIR}/${PN}-2.24.1-logout.patch"
+	epatch "${WORKDIR}/${PN}-2.24.1-po.patch"
+
+	eautomake
+}
+
+pkg_postinst() {
+	local entries="${ROOT}etc/gconf/schemas/panel-default-setup.entries"
+	local gconftool="${ROOT}usr/bin/gconftool-2"
+
+	if [ -e "$entries" ]; then
+		einfo "setting panel gconf defaults..."
+
+		GCONF_CONFIG_SOURCE="$("${gconftool}" --get-default-source | sed "s;:/;:${ROOT};")"
+
+		"${gconftool}" --direct --config-source \
+			"${GCONF_CONFIG_SOURCE}" --load="${entries}"
+	fi
+
+	# Calling this late so it doesn't process the GConf schemas file we already
+	# took care of.
+	gnome2_pkg_postinst
+}