Version bump #129896 by toto.

(Portage version: 2.1_pre7-r5)

3 files changed, 139 insertions, 1 deletions

diff --git a/app-emulation/wine/ChangeLog b/app-emulation/wine/ChangeLog
index 0319a92638b8..adec246c181e 100644
--- a/app-emulation/wine/ChangeLog
+++ b/app-emulation/wine/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/wine
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/ChangeLog,v 1.138 2006/04/14 23:31:23 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/ChangeLog,v 1.139 2006/04/14 23:43:31 vapier Exp $
+
+*wine-0.9.12 (14 Apr 2006)
+
+  14 Apr 2006; Mike Frysinger <vapier@gentoo.org> +wine-0.9.12.ebuild:
+  Version bump #129896 by toto.
 
   14 Apr 2006; Mike Frysinger <vapier@gentoo.org>
   +files/wine-0.9.11-winegcc-short-libnames.patch, wine-0.9.11.ebuild:
diff --git a/app-emulation/wine/files/digest-wine-0.9.12 b/app-emulation/wine/files/digest-wine-0.9.12
new file mode 100644
index 000000000000..790c0f31a65b
--- /dev/null
+++ b/app-emulation/wine/files/digest-wine-0.9.12
@@ -0,0 +1,3 @@
+MD5 f7668e17e731b59c837dfee218554171 wine-0.9.12.tar.bz2 10726811
+RMD160 0fd46a2e4c3df5d379324eb991429d5c03566a44 wine-0.9.12.tar.bz2 10726811
+SHA256 8c02d5153f87d20f1bbedb663fadab3a6213497a9ee944b05b2a87655744d082 wine-0.9.12.tar.bz2 10726811
diff --git a/app-emulation/wine/wine-0.9.12.ebuild b/app-emulation/wine/wine-0.9.12.ebuild
new file mode 100644
index 000000000000..f6b4b915d4d1
--- /dev/null
+++ b/app-emulation/wine/wine-0.9.12.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/wine-0.9.12.ebuild,v 1.1 2006/04/14 23:43:31 vapier Exp $
+
+inherit eutils flag-o-matic multilib
+
+DESCRIPTION="free implementation of Windows(tm) on Unix"
+HOMEPAGE="http://www.winehq.com/"
+SRC_URI="mirror://sourceforge/${PN}/wine-${PV}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="alsa arts cups debug esd gif glut jack jpeg lcms ldap nas ncurses opengl oss scanner truetype xml X"
+RESTRICT="test" #72375
+
+RDEPEND=">=media-libs/freetype-2.0.0
+	media-fonts/corefonts
+	ncurses? ( >=sys-libs/ncurses-5.2 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	X? ( || ( ( x11-libs/libXrandr
+				x11-libs/libXi
+				x11-libs/libXmu
+				x11-libs/libXxf86dga
+				x11-libs/libXxf86vm
+			)
+			virtual/x11
+		)
+	)
+	arts? ( kde-base/arts )
+	alsa? ( media-libs/alsa-lib )
+	esd? ( media-sound/esound )
+	nas? ( media-libs/nas )
+	cups? ( net-print/cups )
+	opengl? ( virtual/opengl )
+	gif? ( media-libs/giflib )
+	jpeg? ( media-libs/jpeg )
+	ldap? ( net-nds/openldap )
+	glut? ( virtual/glut )
+	lcms? ( media-libs/lcms )
+	xml? ( dev-libs/libxml2 dev-libs/libxslt )
+	truetype? ( media-libs/freetype )
+	>=media-gfx/fontforge-20060406
+	scanner? ( media-gfx/sane-backends )
+	amd64? (
+		>=app-emulation/emul-linux-x86-xlibs-2.1
+		>=app-emulation/emul-linux-x86-soundlibs-2.1
+		>=sys-kernel/linux-headers-2.6
+	)"
+DEPEND="${RDEPEND}
+	X? ( || ( ( x11-proto/inputproto
+				x11-proto/xextproto
+				x11-proto/xf86dgaproto
+				x11-proto/xf86vidmodeproto
+			)
+			virtual/x11
+		)
+	)
+	sys-devel/bison
+	sys-devel/flex"
+
+# this will not build as 64bit code
+export ABI=x86
+
+src_unpack() {
+	unpack wine-${PV}.tar.bz2
+	cd "${S}"
+
+	epatch "${FILESDIR}"/wine-0.9.6-force-ddraw-gamma.patch #119931
+	sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in
+	epatch "${FILESDIR}"/wine-gentoo-no-ssp.patch #66002
+	sed -i '/^MimeType/d' tools/wine.desktop || die #117785
+}
+
+config_cache() {
+	local h ans="no"
+	use $1 && ans="yes"
+	shift
+	for h in "$@" ; do
+		[[ ${h} == *.h ]] \
+			&& h=header_${h} \
+			|| h=lib_${h}
+		export ac_cv_${h//[:\/.]/_}=${ans}
+	done
+}
+
+src_compile() {
+	export LDCONFIG=/bin/true
+	use arts    || export ac_cv_path_ARTSCCONFIG=""
+	use esd     || export ac_cv_path_ESDCONFIG=""
+	use scanner || export ac_cv_path_sane_devel="no"
+	config_cache jack jack/jack.h
+	config_cache cups cups/cups.h
+	config_cache alsa alsa/asoundlib.h sys/asoundlib.h asound:snd_pcm_open
+	config_cache nas audio/audiolib.h audio/soundlib.h
+	config_cache xml libxml/parser.h libxslt/pattern.h libxslt/transform.h
+	config_cache ldap ldap.h lber.h
+	config_cache gif gif_lib.h
+	config_cache glut glut:glutMainLoop
+	config_cache jpeg jpeglib.h
+	config_cache oss sys/soundcard.h machine/soundcard.h soundcard.h
+	config_cache lcms lcms.h
+	use x86 && config_cache truetype freetype:FT_Init_FreeType
+
+	strip-flags
+
+	#	$(use_enable amd64 win64)
+	econf \
+		CC=$(tc-getCC) \
+		--sysconfdir=/etc/wine \
+		$(use_with ncurses curses) \
+		$(use_with opengl) \
+		$(use_with X x) \
+		$(use_enable debug trace) \
+		$(use_enable debug) \
+		|| die "configure failed"
+
+	emake -j1 depend || die "depend"
+	emake all || die "all"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+	dodoc ANNOUNCE AUTHORS ChangeLog DEVELOPERS-HINTS README
+}
+
+pkg_postinst() {
+	einfo "~/.wine/config is now deprecated.  For configuration either use"
+	einfo "winecfg or regedit HKCU\\Software\\Wine"
+}